oracle自定义函数：将使用点分隔符的编码转成层级码格式的编码

今天药忘吃喽~ 2023-06-04 04:50 8阅读 0赞

维护一个旧的系统，表设计中只有编码，而没有其他排序相关的字段，然后根据编码排序出现了顺序错乱的问题。

详细地说，其编码设计是使用【.】分隔符的编码，比如1.1.1.1.1、1.1.1.1.2这样的格式。这时候使用编码进行排序，按照数据库字符串排序的规则，则会产生这样的问题：1.11.1排在了1.2.1的前面。这样客户就着急了，哎呀，这个排序不对啊赶紧改一改啊吧啦吧啦的。因此需要寻找解决问题的方法。因为如果从数据库取出来数据之后，再在Java里面再排序的话好像不现实，所以最后我决定还是在数据库层面上解决问题。

具体的解决方案，就是使用PL/SQL写一个自定义函数，用来将使用点分隔符的编码转成层级码格式的编码，比如1.1.1.1转成001001001。

-- 将【.】分割符的编码转成001001这样的格式
    CREATE OR REPLACE FUNCTION POINT_CODE_INTO_ZARO_CODE(POINT_CODE VARCHAR2)
      RETURN VARCHAR2 -- 返回类型
    AS
      VAR_ZERO_CODE        VARCHAR2(100); -- 新编码
      VAR_POINT_COUNT      NUMBER := LENGTH(POINT_CODE) - LENGTH(REPLACE(POINT_CODE, '.', '')); -- 原编码中点符号的数量
      VAR_THIS_POINT_INDEX NUMBER; -- 每次截取开始位置
      VAR_NEXT_POINT_INDEX NUMBER; -- 每次截取结束位置
      VAR_SUB_LENGTH       NUMBER; -- 每次截取长度（ORACLE的字符串截取函数SUBSTR()只支持截取长度的参数，不支持截取结束位置）
      VAR_PART_CODE        VARCHAR2(10); -- 新编码的部分
      BEGIN
        -- 循环将点分隔符替换为0层级码
        WHILE VAR_POINT_COUNT > 0 LOOP
          VAR_THIS_POINT_INDEX := INSTR(POINT_CODE, '.', 1, VAR_POINT_COUNT); -- 取第N个点的截取位置
          VAR_NEXT_POINT_INDEX := INSTR(POINT_CODE, '.', 1, (VAR_POINT_COUNT + 1)); -- 取第N+1个点的截取位置
          IF VAR_NEXT_POINT_INDEX = 0
          THEN
            VAR_PART_CODE := SUBSTR(POINT_CODE, (VAR_THIS_POINT_INDEX + 1));
            VAR_PART_CODE := LPAD(VAR_PART_CODE, '10', '0'); -- 左边填充0
          ELSE
            VAR_SUB_LENGTH := LENGTH(SUBSTR(POINT_CODE, (VAR_THIS_POINT_INDEX + 1))) -
                              LENGTH(SUBSTR(POINT_CODE, VAR_NEXT_POINT_INDEX));
            VAR_PART_CODE := SUBSTR(POINT_CODE, (VAR_THIS_POINT_INDEX + 1), VAR_SUB_LENGTH);
            VAR_PART_CODE := LPAD(VAR_PART_CODE, '10', '0'); -- 左边填充0
          END IF;
          VAR_ZERO_CODE := VAR_PART_CODE || VAR_ZERO_CODE;
          VAR_POINT_COUNT := VAR_POINT_COUNT - 1;
        END LOOP;
        -- 最后拼接上点前面的字符串
        IF VAR_ZERO_CODE IS NULL
        THEN
          VAR_PART_CODE := LPAD(POINT_CODE, '10', '0'); -- 左边填充0R
        ELSE
          VAR_SUB_LENGTH := LENGTH(POINT_CODE) - LENGTH(SUBSTR(POINT_CODE, INSTR(POINT_CODE, '.', 1, 1)));
          VAR_PART_CODE := SUBSTR(POINT_CODE, 1, VAR_SUB_LENGTH);
          VAR_PART_CODE := LPAD(VAR_PART_CODE, '10', '0'); -- 左边填充0R
        END IF;
        VAR_ZERO_CODE := VAR_PART_CODE || VAR_ZERO_CODE;
    
        RETURN VAR_ZERO_CODE;
      END;

创建完自定义函数之后，就可以拿来使用了（我这里定义的是10位的层级码）。

SELECT POINT_CODE_INTO_ZARO_CODE('1.2.3') CODE FROM DUAL; -- 000000000100000000020000000003
    SELECT POINT_CODE_INTO_ZARO_CODE('110') CODE FROM DUAL; -- 0000000110

这样，在排序的时候在ORDER BY子句中加上转换后的编码，就可以实现正常排序了。

"当拥有笃定一件事并耐心长久坚持的能力，你就有了核心竞争力。"

转载于:https://www.cnblogs.com/yanggb/p/10818875.html