《x86汇编语言从实模式到保护模式》学习实验笔记【09】实模式中断

野性酷女 2023-03-02 05:15 19阅读 0赞

### 目录 ###

*  非屏蔽中断和可屏蔽中断
 *  8259芯片中断号
 *  实模式下的中断向量表
 *  中断处理流程
 *  RTC芯片
 *   *  RTC芯片的索引与功能
 *  设置栈指针
 *  安装RTC中断处理程序
 *  初始化RTC芯片
 *   *  更新周期结束中断
     *  周期性中断
 *  示例代码

# 非屏蔽中断和可屏蔽中断 #

对于8086处理器来说，为了处理外部中断，两根中断信号线被引入了处理器中。这两根线的名字叫做NMI和INTR。  
在实模式下，NMI被赋予了统一的中断号2。可屏蔽中断的数量则有很多，而由于INTR引脚只有一个，所以需要使用一个代理，来对这些外部中断源进行仲裁，从而决定让它们中的哪一个优先使用CPU。在个人计算机中使用的最多的就是8259芯片。由于8259芯片只有8个中断输入引脚，所以使用了两片8259进行级联以向8086提供15个中断信号。

第一片8259芯片作为主芯片接在8086的INTR引脚上，第二片8259芯片作为从芯片，接在主芯片的IR2引脚上，从而形成级联关系。

8086处理器允许256个中断，中断号的范围是0~255。上面提到的两片级联的8259芯片负责提供其中的15个，但是中断号并不固定，可以通过编程来进行设置。  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70]  
如上图所示，8259的主芯片IR0引脚连接的是系统定时器/计数器芯片，从芯片的IR0引脚接的是实时时钟芯片RTC。

在8259芯片内部，有一个叫做IMR的8位寄存器，即中断屏蔽寄存器。该寄存器的8位对应着8259芯片的8个中断输入引脚。0表示允许，1表示阻断。

如果想要设置IMR寄存器的值，就需要通过端口号来访问8259芯片。对于主芯片，其端口号是0x20和0x21，从芯片的端口号是0xA0和0xA1。

除了IMR寄存器之外，在8086处理器中，还有一个标志寄存器，其IF位最终决定INTR引脚传入的外部中断能否被最终处理。IF标志位可以通过指令cli和sti来改变。cli用于清除IF标志位，sti用于置位IF标志位。

# 8259芯片中断号 #

8259芯片的8个IR引脚，每一个都被赋予了一个中断号。而且，这些引脚的中断号都是可以改变的，但是只能以芯片为单位来进行整体设置。比如，可以指定芯片的中断号从0x08开始，那么这就意味着，该芯片的引脚IR0~IR7分别对应着中断号0x08~0x0E。

总体上来说，8259芯片的中断优先级是和引脚相关的。IR0引脚的中断优先级最高，IR7最低。

在计算机启动期间，BIOS会初始化中断控制器8259。会将主芯片的中断号设置为从0x08开始，将从芯片的中断号设为从0x70开始。

从上图可知，RTC芯片接在从芯片的IR0引脚，所以RTC芯片的默认中断号是0x70。

# 实模式下的中断向量表 #

8086CPU可以识别256个中断，这些中断处理程序所在的位置并不重要，重要的是，在实模式下，处理器要求将所有中断处理函数的入口点集中存放到内存物理地址0x00000开始的1KB的空间内。

具体来说，我们把这些中断入口地址统称为中断向量表。每个中断入口占用4个字节，从低字到高字分别是偏移地址和段地址。如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 1]  
因为每个中断向量占用4个字节，所以当发生中断、CPU获取到中断号后，会通过硬件将该中断号乘以4，从而获得该中断入口点在中断向量表的偏移地址。

# 中断处理流程 #

1.  保护断点的现场  
    依次将标志寄存器FLAGS、代码段寄存器CS、指令指针寄存器IP压栈；
2.  执行中断处理程序  
    硬件将中断号乘以4后得到中断向量在中断向量表中的偏移地址，接着从该地址处取出中断处理程序的偏移地址和段地址，并分别传送给IP和CS寄存器。之后自然开始执行中断处理程序。
3.  返回到被中断处继续执行  
    所有中断处理程序的最后一条指令都是iret，该指令将依次从栈中弹出IP、CS和FLAGS的原始内容，之后原主程序恢复执行。

值得一提的是，当NMI发生时，CPU自动生成中断号2，之后处理过程和普通可屏蔽中断一样。

# RTC芯片 #

早期的RTC芯片是摩托罗拉MS146818B，是一块单独的芯片。现在则直接集成在了ICH内部。  
RTC芯片除了提供日期和时间功能之外，还提供闹钟和周期性的中断功能。RTC芯片通过两个端口来对外提供服务。第一个端口是0x70或0x74，作为索引端口来指定要访问的内容。第二个端口是0x71或者0x75，作为数据端口来读写相应单元里的内容。

此外，需要特别指出的是，端口0x70的最高位（位7）控制着NMI中断信号是否能到达处理器。NMI的中断源通过一个与非门连接到CPU，而CPU的NMI引脚是高电平有效，而中断INTR引脚是低电平有效。

而端口0x70的最高位控制着与非门的输出，当端口0x70的最高位为0时，允许中断到达处理器；当它为1时则阻断所有的NMI信号。其他的7个比特用于指定CMOS RAM单元的索引号。

## RTC芯片的索引与功能 ##

对于RTC芯片中存储的日期和时间，其格式为BCD码。但是如果需要，也可以按正常的二进制数来表示。比如，如果该字节的值为0x25，那么其对应的十进制值是25。

除了日期和时间之外，还有四个寄存器，其索引值为0xA~0xD。这四个寄存器都是8位的寄存器，其中寄存器A和寄存器B是对RTC芯片进行整体设置，而寄存器C和寄存器D是标志寄存器。

它们的具体功能如下图所示：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 2]

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 3]

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 4]

![在这里插入图片描述][20200804220628292.jpg]

通过上表可知，当中断产生时，可以通过寄存器C来识别中断的原因。读取该寄存器后，该寄存器的值就被清零。需要注意，每次中断发生之后，一定要读一下RTC的寄存器C，否则只发生一次中断。

# 设置栈指针 #

x86CPU在设计时就规定，当遇到修改段寄存器SS的指令时，在这条指令和下一条指令执行时，CPU自动禁止中断，以此来保护栈。因此，当我们设置了段寄存器SS之后，下一条指令一定要是设置SP的指令。

# 安装RTC中断处理程序 #

在安装中断处理程序之前，必须要先关中断。因为当中断向量表被修改一半时，如果发生了0x70号中断，那么将会产生不可预料的后果。即我们需要先使用cli指令关中断。

由本文之前的介绍可知，RTC芯片的中断引脚接在从片IR0引脚上，而从片的IR0引脚则接在IR2上。由于从8259芯片的中断号起始值是0x70，所以RTC中断对应的中断号是0x70。为此，我们需要向0x70乘以4的地址写入中断向量入口地址。我们把偏移地址写为0，段地址写为重载后的中断段地址。

mov ax, 0x70
    shl ax, 2
    mov di, ax
    mov word [es:di], 0
    
    pop ds
    ;now ds point to app_header
    mov ax, [interrupt_segment]
    mov word [es:di+2], ax

# 初始化RTC芯片 #

RTC芯片可以产生多种类型的中断，由于RTC只有一根中断线，所以当发生中断时，我们还需要在中断处理程序中去查询寄存器C，来检查发生中断的具体原因。

RTC芯片最常用的中断有三种类型：更新周期结束中断、周期性中断和闹钟中断。

首先，最简单的中断是更新周期结束中断。更新周期是1秒，所以该中断每秒发生一次。第二，如果采用周期性中断，则还需要设置寄存器A中分频电路的分频系数。此外，还要使能寄存器B中的周期性中断允许标志PIE。对于第三种中断，闹钟中断，由于书中没有具体介绍，所以这里也略过，以后有机会再说。

## 更新周期结束中断 ##

如果满足以下两个条件：

1.  寄存器B的第7位（更新周期禁止位）清零，即允许周期更新中断
2.  将寄存器A的\[6:4\]位设置为二进制0b010，即将分频电路选择设置为32.768KHz的时钟频率

那么，更新周期中断会每秒发生一次。

当更新周期结束中断发生后，寄存器C中的第4比特位（更新结束标志UF）会被置1，表明本中断已发生。之后读取一下RTC的寄存器C，可以使得该寄存器的所有位被清零，从而告诉RTC芯片，中断已经得到了处理。如果不读取寄存器C的话，将不会再次产生那些被置1的比特位所对应的中断类型。当读取了寄存器C之后，8259芯片知道了对应的中断处理过程已经开始执行。

在8259芯片内部，还有一个8位的中断服务寄存器ISR。它的每一位对应着一个中断输入引脚。当中断处理过程开始时，8259芯片会将ISR对应的比特位置1。所以，当中断处理完毕时，需要将8259芯片的ISR寄存器对应位清零。清零的方法向8259芯片发送中断结束命令EOI(End Of Interrupt)。

如果外部中断是8259主芯片处理的，那么EOI命令仅发送给主芯片即可，端口号是0x20；如果外部中断是由从芯片处理的，那么EOI命令既要发往从芯片，之后也要发送给主芯片。代码如下所示：

mov al,0x20                        ;中断结束命令EOI 
    out 0xa0,al                        ;向从片发送 
    out 0x20,al                        ;向主片发送

## 周期性中断 ##

想要使能周期性中断，那么除了使能寄存器B中第6位周期性中断允许PIE之外，还要设置分频电路的分节点，即寄存器A的\[3:0\]比特位。这几位用于设置周期性中断产生的速率。具体值含义详见本文上面的寄存器A功能位说明。

为了使中断周期为250ms，即1秒钟产生4次中断，那么我们需要将寄存器A的RS位设置为0x1110，具体代码如下所示：

mov	al, 0x0A
    or al,	0x80	;禁止NMI中断
    out	0x70, al
    in al, 0x71
    and al, 0xF0	;清除寄存器A的低4比特位，即RS
    or	al, 0xE		;设置RTC寄存器A的RS，使其每秒钟发生4次中断
    out 0x71, al

# 示例代码 #

我们在本系列第8篇博客代码的基础之上引入中断处理代码。  
首先是位于mbr上的加载器对应的汇编代码：

app_start_lba equ 512
    physical_address equ 0x12340
    
    segment loader align=16 vstart=0x7c00
    	xor ax, ax
    	mov ss, ax
    	mov sp, ax
    
    	
    	mov ax, [loading_physical_address]
    	mov dx, [loading_physical_address+2]
    	mov bx, 16
    	div bx
    	
    	mov es, ax
    	mov di, dx
    
    	mov si, [loading_sector_lba28]
    	mov bx, [loading_sector_lba28+2]
    	
    	call readSectorFromDisk
    	
    	;get app total size
    	mov ax, [es:0]
    	mov dx, [es:2]
    	mov bx, 512
    	div bx
    	
    	cmp dx, 0
    	jne @1
    	dec ax
    @1:
    	;set loop count
    	mov cx, ax
    	mov si, [loading_sector_lba28]
    	mov bx, [loading_sector_lba28+2]
    	
    	;before read remain sectors, save es
    	push es
    	;read next sector
    .readRemainSectors:
    	mov ax, es
    	add ax, 512/16
    	mov es, ax
    	xor di, di
    	
    	add si, 1
    	adc bx, 0
    	
    	call readSectorFromDisk
    	loop .readRemainSectors
    	
    	;restore es
    	pop es
    ;relocate entry point
    	mov ax, [es:6]
    	mov bx, [es:8]
    	call calRelocateSegmentAddr
    	mov [es:6], ax
    	
    ;relocate segment table
    	mov cx, [es:0xA]
    	mov si, 0xC
    .relocateSegments:
    	mov ax, [es:si]
    	mov bx, [es:si + 2]
    	call calRelocateSegmentAddr
    	mov [es:si], ax
    	add si, 4
    	loop .relocateSegments
    
    	
    	mov ax, [es:6]
    	push ax
    	mov ax, [es:4]
    	push ax
    	
    	;before execute the app, set es and ds to app header
    	mov ax, es
    	mov ds, ax
    	retf
    
    calRelocateSegmentAddr:
    	;ax low word of segment address
    	;bx high word of segment address
    	push bx
    	push cx
    	push dx
    	
    	mov cx, [loading_physical_address]
    	mov dx, [loading_physical_address+2]
    	add ax, cx
    	adc dx, bx
    	mov bx, 16
    	div bx
    	
    	
    	pop dx
    	pop cx
    	pop bx
    	ret
    	
    
    
    
    loading_sector_lba28 dd app_start_lba
    loading_physical_address dd physical_address
    
    readSectorFromDisk:
    	;从硬盘读取一个逻辑扇区
    	;BX:SI=起始逻辑扇区号
    	;ES:DI=目标缓冲区地址
    	;LBA28(BX:SI)
    DataRegister equ 0x1f0
    FeatureRegister equ 0x1f1
    SectorRegister equ 0x1f2
    LBAlowRegister equ 0x1f3
    LBAmidRegister equ 0x1f4
    LBAhighRegister equ 0x1f5
    DeviceRegister equ 0x1f6
    CommandRegister equ 0x1f7
    
    ReadCMD	 	equ 0x20
    WriteCMD	equ 0x30
    IDCMD		equ 0xEC
    
    	push ax
    	push bx
    	push cx
    	push dx
    	push di
    
    	mov ax, si
    	
    	mov dx, LBAlowRegister
    	out dx, al
    
    	mov dx, LBAmidRegister
    	shr ax, 8
    	out dx, al
    
    	mov dx, LBAhighRegister
    	mov ax, bx
    	out dx, al
    	
    	mov dx, DeviceRegister
    	;LBA28 mode, master disk
    	and ah, 0x0F
    	mov al, 0xe0
    	or al, ah
    	out dx, al
    	
    	mov dx, SectorRegister
    	mov al, 0x1
    	out dx, al
    	
    	mov dx, CommandRegister 
    	mov al, ReadCMD
    	out dx, al
    	
    .wait4Ready:
    	in al, dx
    	and al, 0x88
    	cmp al, 0x08
    	jnz .wait4Ready
    	
    	mov cx, 256
    	mov dx, DataRegister
    .readSectorData:
    	in ax, dx
    	mov word [es:di], ax
    	add di, 2
    	loop .readSectorData
    
    	pop di
    	pop dx
    	pop cx
    	pop bx
    	pop ax
    
    	ret
    	
    
    times 510-($-$$) db 0
    db 0x55,0xaa

下面是应用程序代码，rtc.s:

VideoIndexPort equ 0x3D4
    VideoDataPort equ 0x3D5
    
    CursorPosHigh8Index equ 0xE
    CursorPosLow8Index equ 0xF
    
    section header align=16 vstart=0
    ;app length
    app_header dd (app_end - app_header)
    
    ;app entry point
    dw start	;0x4
    dd section.mainProgram.start	;0x6
    
    ;segment relocator item count
    dw	(header_end - interrupt_segment)/4		;0xA
    
    ;segment relocator
    interrupt_segment dd section.interrupt.start		;0xC
    mainProgram_segment dd section.mainProgram.start
    mydata_1_segment dd section.mydata_1.start
    mystack_segment dd section.mystack.start
    
    header_end:
    
    SECTION interrupt align=16 vstart=0x0
    	;更新结束中断发生，开始处理
    	push es
    	push bx
    	push ax
    	push di
    	
    	mov al, 0xa
    	or al, 0x80
    	out 0x70, al
    	
    .wait4UpdateEnd:	
    	in al, 0x71
    	test al, 0x80
    	jne .wait4UpdateEnd
    	
    	
    	mov ax, 0xb800
    	mov es, ax
    	
    	mov al, 0
    	or al, 0x80
    	out 0x70, al
    	
    	in al, 0x71
    	push ax
    	
    	mov al, 0x2
    	or al, 0x80
    	out 0x70, al
    	
    	in al, 0x71
    	push ax
    	
    	mov al, 0x4
    	or al, 0x80
    	out 0x70, al
    	
    	in al, 0x71
    	push ax
    	
    	mov al, 0x7
    	or al, 0x80
    	out 0x70, al
    	
    	in al, 0x71
    	push ax
    	
    	mov al, 0x8
    	or al, 0x80
    	out 0x70, al
    	
    	in al, 0x71
    	push ax
    	
    	mov al, 0x9
    	or al, 0x80
    	out 0x70, al
    	
    	in al, 0x71
    	push ax
    	
    	pop ax
    	call bcd2ASCII
    	
    	mov bx, 160*15+70
    	mov [es:bx], ah
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov [es:bx], al
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov byte [es:bx], '-'
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	
    	pop ax
    	call bcd2ASCII
    	mov [es:bx], ah
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov [es:bx], al
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov byte [es:bx], '-'
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	
    	pop ax
    	call bcd2ASCII
    	mov [es:bx], ah
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov [es:bx], al
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov byte [es:bx], ' '
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	
    	pop ax
    	call bcd2ASCII
    	mov [es:bx], ah
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov [es:bx], al
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov byte [es:bx], ':'
    	;mov byte [es:bx+1], 0x0f
    	mov al, [es:bx+1]
    	not al
    	and al, 0x7F
    	mov [es:bx+1], al
    	add bx, 2
    	
    	pop ax
    	call bcd2ASCII
    	mov [es:bx], ah
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov [es:bx], al
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov byte [byte es:bx], ':'
    	;mov byte [es:bx+1], 0x0f
    	mov al, [es:bx+1]
    	not al
    	and al, 0x7F
    	mov [es:bx+1], al
    	add bx, 2
    	
    	pop ax
    	call bcd2ASCII
    	mov [es:bx], ah
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    	mov [es:bx], al
    	mov byte [es:bx+1], 0x0f
    	add bx, 2
    
    	mov al,0x20                        ;中断结束命令EOI 
    	out 0xa0,al                        ;向从片发送 
    	out 0x20,al                        ;向主片发送 
    	
    	mov al,0x0c                        ;寄存器C的索引。且开放NMI 
    	out 0x70,al
    	in al,0x71                         ;读一下RTC的寄存器C，否则只发生一次中断
    		
    	pop di
    	pop ax
    	pop bx
    	pop es
    	iret
    
    bcd2ASCII:
    	;将al中的两位bcd码转换为两个字节存放在ax中
    	mov ah, al
    	and al, 0xF
    	add al, 0x30
    	
    	shr ah, 4
    	add ah, 0x30
    	ret
    
    section mainProgram align=16 vstart=0
    start:
    	;now es ds point to app_header
    	cli
    	mov ax, [mystack_segment]
    	mov ss, ax
    	mov sp, ax
    
    	push es
    	push ds
    		
    	mov ax, [es:mydata_1_segment]
    	mov ds, ax
    	
    	
    	mov ax, installIntHandlerMsg
    	call printString
    	
    
    	xor ax, ax
    	mov es, ax
    	
    	mov ax, 0x70
    	shl ax, 2
    	mov di, ax
    	mov word [es:di], 0
    
    	pop ds
    	;now ds point to app_header
    	mov ax, [interrupt_segment]
    	mov word [es:di+2], ax
    	
    	pop es
    	
    	mov ax, [es:mydata_1_segment]
    	mov ds, ax
    		
    	mov ax, installDoneMsg
    	call printString
    	
    	mov ax, initRTCMsg
    	call printString
    	
    	
    	;关周期性中断、闹钟结束中断，开更新结束中断
    	;设置数据模式为BCD，小时格式为24小时制
    	mov al, 0xb
    	or al, 0x80
    	out 0x70, al
    	
    	mov al, 0x12
    	out 0x71, al
    	
    	sti
    	mov ax, initRTCDoneMsg
    	call printString
    	
    	in al,0xa1                         ;读8259从片的IMR寄存器 
    	and al,0xfe                        ;清除bit 0(此位连接RTC)
    	out 0xa1,al                        ;写回此寄存器 
    	
    	mov al,0x0c
    	out 0x70,al
    	in al,0x71                         ;读RTC寄存器C，复位未决的中断状态
    
    	mov ax, 0xb800
    	mov es, ax
    	mov di, 160*10
    	mov byte [es:di], '$'
    	mov byte [es:di+1], 0x0f
    myloop:
    	hlt
    	mov al, [es:di+1]
    	not al
    	and al, 0x7F
    	mov [es:di+1], al
    	
    	jmp myloop
    
    getCursorPosition:
    	push dx
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	mov ah, al
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	in al, dx
    	
    	pop dx
    	ret
    
    setCursorPosition:
    	push ax
    	push bx
    	push dx
    	
    	mov bx, ax
    	
    	mov dx, VideoIndexPort
    	mov al, CursorPosHigh8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bh
    	out dx, al 
    
    	mov dx, VideoIndexPort
    	mov al, CursorPosLow8Index
    	out dx, al
    
    	mov dx, VideoDataPort
    	mov al, bl
    	out dx, al
    	
    	pop dx
    	pop bx
    	pop ax	
    	ret
    	
    printString:
    	push ax
    	push si
    	
    	;save string start address to si
    	mov si, ax
    	
    @1: mov al, [si]
    	cmp al, 0
    	je @2
    	
    	call printCharacter
    	
    	inc si
    	jmp @1
    	
    @2:
    	pop si
    	pop ax
    	
    	ret	
    
    printCharacter:
    	push es
    	push ds
    	push ax
    	push di
    	push bx
    	push cx
    	
    	mov bx, ax
    	
    	;set video buffer addr
    	mov ax,0xb800
       	mov es, ax
       	   		
    	;get cursor pos to ax
    	call getCursorPosition
    	;move current cursor pos to di
    	mov di, ax
    	;1 character consumes 2 bytes
    	shl di, 1
    
    	cmp di, 4000
    	;test if the screen is full, if screen is full, just return
    	je .doneWithPrintCharacter
    	
    	;before output, test if it is carriage return
    	cmp bl, 0xD
    	je .handleCarriageReturn
    	
    	cmp bl, 0xA
    	je .handleNewLine
    	
    	
    	mov byte [es:di], bl	
    	inc di
    	mov byte [es:di], 0x0f
    	inc di
    	jmp .doneWithPrintCharacter
    	
    .handleCarriageReturn:
    	;move cursor to the front of current line
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	mul bh
    	shl ax, 1
    	mov di, ax
    	jmp .doneWithPrintCharacter
    	
    .handleNewLine:
    	mov ax, di
    	shr ax, 1
    	mov bh, 80
    	div bh
    	cmp al, 24
    	jl .addAnotherNewLine
    	
    	;roll the Screen
    	push di
    	mov ax,0xb800
    	mov ds,ax
    	mov es,ax
    	cld
    	mov cx, 1920
    	mov di, 0
    	mov si, 160
    	rep movsw
    	;clear screen last line
    	mov bx, 3840                     
    	mov cx, 80
     .cls:
    	mov word [es:bx], 0x0720
    	add bx, 2
    	loop .cls
    	; keep the cursor in the same place of the last line
    	pop di
    	jmp .doneWithPrintCharacter
    	
    .addAnotherNewLine:
    	;just add another new line if it is not the last line
    	add di, 160
    .doneWithPrintCharacter:	
    	;write new cursor pos to video card
    	mov ax, di
    	shr ax, 1
    	call setCursorPosition
    	
    	pop cx
    	pop bx
    	pop di
    	pop ax
    	pop ds
    	pop es
    	ret
    
    section mydata_1 align=16 vstart=0
    
    installIntHandlerMsg: db 'Installing RTC Interrupt Handler', 0xd, 0xa, 0x0
    installDoneMsg: db 'RTC Interrupt handler is installed.', 0xd, 0xa, 0x0
    initRTCMsg: db 'Now init rtc settings...', 0xd, 0xa, 0x0
    initRTCDoneMsg: db  'rtc settings done.', 0xd, 0xa, 0x0
    
    
    section mystack align=16 vstart=0
    resb 256
    stack_end:
    
    section tail align=16
    app_end:

编译上述两个汇编文件如下所示：

> $ nasm -f bin loader.s -o loader.bin  
> $ nasm -f bin rtc.s -o rtc.bin  
> rtc.s:446: warning: uninitialized space declared in mystack section: zeroing \[-w+other\]

之后使用Fix工具将loader.bin文件烧写至第0扇区，将rtc.bin文件烧写至512扇区，命令如下所示：

> $ FixVhdWr -r loader.bin -w ~/VirtualBoxVMs/x86AsmLab/x86AsmLab.vhd -a 0  
> Data: loader.bin  
> VHD: /home/macrofun/VirtualBoxVMs/x86AsmLab/x86AsmLab.vhd (offset LBA: 0)  
> Total bytes to write: 512  
> Total sectors to write: 1  
> Total bytes written: 512  
> Total sectors written: 1  
> $  
> $ FixVhdWr -r rtc.bin -w ~/VirtualBoxVMs/x86AsmLab/x86AsmLab.vhd -a 512  
> Data: rtc.bin  
> VHD: /home/macrofun/VirtualBoxVMs/x86AsmLab/x86AsmLab.vhd (offset LBA: 512)  
> Total bytes to write: 1104  
> Total sectors to write: 3  
> Total bytes written: 1104  
> Total sectors written: 3

之后启动虚拟机，程序运行的效果动态图如下所示：  
![在这里插入图片描述][20200808225425855.gif]

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70]: /images/20230208/25e22cd24052478b84ab24340b2db9d8.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 1]: /images/20230208/a046c618f7864c37bde8a6e77c2e9dc0.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 2]: /images/20230208/e5dbb2b556ff4dff9524a5b4fc6994e2.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 3]: /images/20230208/ceb94687e76b466daf767ffe25b24b1a.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L0Jha2VyVGhlR3JlYXQ_size_16_color_FFFFFF_t_70 4]: /images/20230208/3e62e115e8d94ec7b12677f6b1ea15c5.png
[20200804220628292.jpg]: /images/20230208/31f6ab2448e94680ab103dcf4ea1cf62.png
[20200808225425855.gif]: /images/20230208/40ba5d6632e445dd9986f9175c0a4857.png