Hive学习总结（四）之hive数据库操作(上)

迈不过友情╰ 2023-02-21 06:49 49阅读 0赞

### hive数据库操作（上） ###

*   *   *  1、DDL---数据定义语言
         *   *  1.1数据库操作
             *  1.2表操作
             *  1.2.1管理表与外部表
             *  1.2.2分区表
         *  2、DML---数据操作语言
         *   *  2.1数据导入
             *  2.2数据导出

### 1、DDL—数据定义语言 ###

#### 1.1数据库操作 ####

*  **创建数据库**

create database db_hive;

避免要创建的数据库已经存在错误，增加if not exists判断。（标准写法）

create database if not exists db_hive;

创建一个数据库，指定数据库在HDFS上存放的位置，HDFS会有一个默认存储路径

create database db_hive2 location '/db_hive2.db';

*  **查看数据库信息**  
    显示数据库

show databases;
    
    show databases like 'db_hive*'; #模糊查询

显示数据库详细信息，extended

desc database extended db_hive;

切换当前数据库

use db_hive;

*  **修改数据库**  
    使用ALTER DATABASE命令为某个数据库的DBPROPERTIES设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。
 *  **删除数据库**  
    删除空数据库，如果删除的数据库不存在，最好采用 if exists判断数据库是否存在

drop database db_hive;
    
    drop database if exists db_hive2;

如果数据库不为空，可以采用cascade命令，强制删除

drop database db_hive cascade;

#### 1.2表操作 ####

*  **创建表**  
    1．建表语法

CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name 
    [(col_name data_type [COMMENT col_comment], ...)] 
    [COMMENT table_comment] 
    [PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)] 
    [CLUSTERED BY (col_name, col_name, ...) 
    [SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS] 
    [ROW FORMAT row_format] 
    [STORED AS file_format] 
    [LOCATION hdfs_path]

字段解释说明  
（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。  
（2）EXTERNAL关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。  
（3）COMMENT：为表和列添加注释。  
（4）PARTITIONED BY创建分区表  
（5）CLUSTERED BY创建分桶表  
（6）SORTED BY不常用  
（7）ROW FORMAT  
DELIMITED \[FIELDS TERMINATED BY char\] \[COLLECTION ITEMS TERMINATED BY char\]  
\[MAP KEYS TERMINATED BY char\] \[LINES TERMINATED BY char\]  
| SERDE serde\_name \[WITH SERDEPROPERTIES (property\_name=property\_value, property\_name=property\_value, …)\]  
用户在建表的时候可以自定义SerDe或者使用自带的SerDe。如果没有指定ROW FORMAT 或者ROW FORMAT DELIMITED，将会使用自带的SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的SerDe，Hive通过SerDe确定表的具体的列的数据。  
SerDe是Serialize/Deserilize的简称，目的是用于序列化和反序列化。  
（8）STORED AS指定存储文件类型  
常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）  
如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。  
（9）LOCATION ：指定表在HDFS上的存储位置。  
（10）LIKE允许用户复制现有的表结构，但是不复制数据。

*  **修改表**  
    重命名表

ALTER TABLE table_name RENAME TO new_table_name

增加/修改/替换列信息

更新列

ALTER TABLE table_name CHANGE [COLUMN] col_old_name col_new_name column_type [COMMENT col_comment] [FIRST|AFTER column_name]

增加和替换列

ALTER TABLE table_name ADD|REPLACE COLUMNS (col_name data_type [COMMENT col_comment], ...)

注：ADD是代表新增一字段，字段位置在所有列后面(partition列前)，REPLACE则是表示替换表中所有字段。

删除表

drop table emails;

清除表中数据  
Truncate只能删除管理表，不能删除外部表中数据

truncate table student;

#### 1.2.1管理表与外部表 ####

默认创建的表都是所谓的管理表，有时也被称为内部表。`当删除一个管理表时，Hive也会删除这个表中数据。`管理表不适合和其他工具共享数据。  
外部表通过`external`创建，Hive并非认为其完全拥有这份数据。`删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉。`

create external table if not exists emails(
    email string,
    name string,
    password string
    )
    row format delimited fields terminated by '\t';

*  **管理表和外部表的使用场景：**  
    每天将收集到的网站日志定期流入HDFS文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT进入内部表。
 *  **管理表与外部表的互相转换：**

#修改内部表为外部表
    alter table emails set tblproperties('EXTERNAL'='TRUE');  
    
    #('EXTERNAL'='TRUE')和('EXTERNAL'='FALSE')为固定写法，区分大小写！

#### 1.2.2分区表 ####

*  创建分区表语法 **partitioned by (month string)**

create external table if not exists emails(
    email string,
    name string,
    password string
    )
    partitioned by (month string)
    row format delimited fields terminated by '\t';

*  加载数据到分区表中

load data local inpath '/opt/module/datas/dept.txt' into table mydb.emails partition(month='202006');

*  查询分区表中数据

select * from emails where month='202006';

*  增加分区  
    创建单个分区

alter table  emails add partition(month='202006') ;

同时创建多个分区`（空格）`

alter table  emails add partition(month='202005') partition(month='202006');

*  删除分区  
    删除单个分区

alter table  emails drop partition(month='202006') ;

同时删除多个分区`（逗号）`

alter table  emails drop partition(month='202005') ,partition(month='202006');

*  查看分区表有多少分区

show partitions emails;

*  查看分区表结构

desc formatted eamils;

*  创建二级分区表

create external table if not exists emails(
    email string,
    name string,
    password string
    )
    partitioned by (month string,day string)
    row format delimited fields terminated by '\t';

### 2、DML—数据操作语言 ###

#### 2.1数据导入 ####

*  **装载数据（Load）**

hive> load data [local] inpath '/opt/module/datas/student.txt' overwrite | into table student [partition (partcol1=val1,…)];

（1）load data:表示加载数据  
（2）local:表示从本地加载数据到hive表；否则从HDFS加载数据到hive表  
（3）inpath:表示加载数据的路径  
（4）overwrite:表示覆盖表中已有数据，否则表示追加  
（5）into table:表示加载到哪张表  
（6）student:表示具体的表  
（7）partition:表示上传到指定分区

*  **插入数据（Insert）**  
    基本模式插入（根据单张表查询结果）

insert overwrite table emails partition(month='201908')
                 select id, name from emails_t1 where month='201909';

多插入模式（根据多张表查询结果）

from emails
                  insert overwrite table emails partition(month='201907')
                  select id, name where month='201909'
                  insert overwrite table emails_t1 partition(month='201906')
                  select id, name where month='201909';

上传数据到hdfs上

dfs -put /opt/module/datas/student.txt

#### 2.2数据导出 ####

*  数据导出  
    将查询的结果导出到本地

insert overwrite local directory '/opt/module/datas/export/email1'
                select * from emails;

将查询的结果格式化导出到本地

insert overwrite local directory '/opt/module/datas/export/email1'
               ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t'   
               select * from  emails;

将查询的结果导出到HDFS上(没有local)

insert overwrite directory '/user/atguigu/email2'
                 ROW FORMAT DELIMITED FIELDS TERMINATED BY '\t' 
                 select * from emails;

*  Hadoop命令导出到本地

dfs -get /user/hive/warehouse/email/month=201909/000000_0  /opt/module/datas/export/email3.txt;

*  Hive Shell 命令导出

bin/hive -e 'select * from default.email;'  >  /opt/module/datas/export/emailst4.txt;

*  Export导出到HDFS上

export table default.emails to '/user/hive/warehouse/export/email';